New Frost m4a1 - | Zombie Plague

Deleted

Posts: 0

New Frost m4a1 - Jan 16, 2022 19:54:18 GMT

Quote

Post by Deleted on Jan 16, 2022 19:54:18 GMT

a happy day to me
I'm still updating but I bring the m4a1 frost edited by me hope you like it

Original version - Raheem

Edited by - Linu[X]

Custom trail by - ShaunCraft15

removed Gibs

removed Ice cube model

version _V1 = only glow

version _V2 = glow and explosion and ring

version _V3 = glow and ring

SMA & AMXX

Screenshot: imgur.com/bT0TYlL
Download: www.mediafire.com/file/6aclx7i7itrw2z8/New_Frost_m4a1_-_works_on_zp5.0.rar/file

Last Edit: Jan 16, 2022 19:57:05 GMT by Deleted

ShaunCraft15
Junior Member

An Junior AMXX-Coder, My Motto Is Private+Less = PrivateLess

Posts: 138

New Frost m4a1 - Jan 17, 2022 17:06:11 GMT

Quote

Post by ShaunCraft15 on Jan 17, 2022 17:06:11 GMT

if u say zp50 u need use zp50 grenade frost natives Like This

/*
Original version - Raheem
Edited by - Linu[X]
Custom trail by - ShaunCraft15

removed Gibs 
removed Ice cube model
*/

#include <amxmodx>
#include <zombieplague>
#include <hamsandwich>
#include <fakemeta>
#include <cstrike>
#include <engine>
#include <fun>
#include <zp50_grenade_frost>

const PRIMARY_WEAPONS_BIT_SUM = (1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_SG550)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|
(1<<CSW_AWP)|(1<<CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_P90)

#define write_coord_fl(%1) engfunc(EngFunc_WriteCoord, %1)
#define message_begin_fl(%1,%2,%3,%4) engfunc(EngFunc_MessageBegin, %1, %2, %3, %4)

new const V_M4A1_MODEL[] = "models/v_m4a1.mdl"
new const P_M4A1_MODEL[] = "models/p_m4a1.mdl"
new const W_M4A1_MODEL[]    = "models/w_m4a1.mdl"
new const W_OLD_M4A1_MODEL[]    = "models/w_m4a1.mdl"

new g_iItemID, g_iM4A1FrostSpr, g_iMaxPlayers, g_iHudSync, g_iFreezeDmg, g_fFrostTime, g_iDmgMultiplier, m_spritetexture
new bool:g_bHasFrostM4A1[33]
new g_iDmg[33]

public plugin_init()
{
	register_plugin("ZP - Frost m4a1 (ring)", "1.0", "Linu[X]")
	
	// Cvars
	g_fFrostTime = register_cvar("zp_frost_m4a1_time", "2.0") // Freeze Time. It's Float you can make it 0.5
	g_iFreezeDmg = register_cvar("zp_freezing_m4a1_damage", "1000") // Damage Requried So Zombie got Frozen
	g_iDmgMultiplier = register_cvar("zp_multiplier_m4a1_damage", "2") // Multiplie Weapon Damage

	// Message IDS
	g_iHudSync = CreateHudSyncObj()

	// Server Max Slots
	g_iMaxPlayers = get_maxplayers()
	
	// ITEM NAME & COST
	g_iItemID = zp_register_extra_item("Frost m4a1 -\r Damage x2", 100, ZP_TEAM_HUMAN) 
	
	// Events
	register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
	register_event("WeapPickup","CheckModel","b","1=19")
	register_event("CurWeapon","CurrentWeapon","be","1=1")
	register_event("DeathMsg", "EventDeathMsg", "a")
	
	// Forwards
	register_forward(FM_SetModel, "fw_SetModel")
	
	// Hams
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	RegisterHam(Ham_TraceAttack, "player", "fw_FrostCount", 1) // countdown to frost!
		
	RegisterHam(Ham_Item_AddToPlayer, "weapon_m4a1", "fw_FrostM4A1AddToPlayer")
	
	RegisterHam(Ham_TraceAttack, "func_breakable", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "func_wall", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "func_door", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "func_door_rotating", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "func_plat", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "func_rotating", "Ham_TraceAttack_Player", false) 
	RegisterHam(Ham_TraceAttack, "player", "Ham_TraceAttack_Player", false)
	RegisterHam(Ham_TraceAttack, "worldspawn", "Ham_TraceAttack_Player", false)
}

public plugin_precache() 
{
	// Models
	precache_model(V_M4A1_MODEL)
	precache_model(P_M4A1_MODEL)
	precache_model(W_M4A1_MODEL)
	
	// Sounds
	precache_sound("warcraft3/impalehit.wav")
	
	// Sprites
	g_iM4A1FrostSpr = precache_model("sprites/shockwave.spr")
	m_spritetexture = precache_model( "sprites/lighting.spr")
}

public client_putinserver(id)
{
	g_bHasFrostM4A1[id] = false
}

public client_disconnected(id)
{
	g_bHasFrostM4A1[id] = false
}

public zp_extra_item_selected(player, itemid)
{
	if (itemid == g_iItemID) 
	{
		drop_weapons(player, 1)
		g_bHasFrostM4A1[player] = true
		ham_strip_weapon(player, "weapon_m4a1")
		give_item(player, "weapon_m4a1")
		cs_set_user_bpammo(player, CSW_M4A1, 90)
	}
}

public zp_user_infected_post(infected, infector)
{
	if (g_bHasFrostM4A1[infected])
	{
		g_bHasFrostM4A1[infected] = false
	}
}

public zp_user_humanized_post(id)
{
	g_bHasFrostM4A1[id] = false
	g_iDmg[id] = 0
}

public event_round_start()
{
	for (new i = 1; i <= g_iMaxPlayers; i++)
	{
		g_bHasFrostM4A1[i] = false
		g_iDmg[i] = 0
	}
}

public fw_FrostCount(iEnt, iAttacker, Float:flDamage, Float:fDir[3], ptr, iDamageType)
{
	if(!is_user_alive(iAttacker))
		return 
	
	if(get_user_weapon(iAttacker) != CSW_M4A1 || !g_bHasFrostM4A1[iAttacker])
		return
	
	set_hudmessage(0, 50, 200, -1.0, 0.17, 0, 6.0, 0.3, 0.1, 0.2)
	ShowSyncHudMsg(iAttacker, g_iHudSync, "%d/%d", g_iDmg[iAttacker], get_pcvar_num(g_iFreezeDmg))
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
	if(!is_user_connected(victim) || !is_user_connected(attacker) || zp_get_user_nemesis(victim) || attacker == victim || !attacker)
		return HAM_IGNORED

	if(g_bHasFrostM4A1[attacker] && (get_user_weapon(attacker) == CSW_M4A1))
		SetHamParamFloat(4, damage * get_pcvar_num(g_iDmgMultiplier))
	
	// For Frost Effect Ring
	static Float:originF[3]
	pev(victim, pev_origin, originF)
	
	// For Frost Effect Sound
	static originF2[3] 
	get_user_origin(victim, originF2)
	
	if((get_user_weapon(attacker) == CSW_M4A1) && g_bHasFrostM4A1[attacker])
	{
		g_iDmg[attacker] += (floatround(damage) * get_pcvar_num(g_iDmgMultiplier))
	}
	
	if((g_iDmg[attacker] >= get_pcvar_num(g_iFreezeDmg)) && (get_user_weapon(attacker) == CSW_M4A1) && g_bHasFrostM4A1[attacker])
	{
		zp_grenade_frost_set(victim, true)
		set_task(get_pcvar_float(g_fFrostTime), "removefreeze", victim)
		FrostEffectRing(originF)
		FrostEffectSound(originF2)
		g_iDmg[attacker] = 0
		
	}
	return HAM_IGNORED
}
public removefreeze(id) zp_grenade_frost_set(id, false)

public CheckModel(id)
{
	if(zp_get_user_survivor(id))
		return PLUGIN_HANDLED
	
	if (is_user_alive(id))
	{
		set_pev(id, pev_viewmodel2, V_M4A1_MODEL)
		set_pev(id, pev_weaponmodel2, P_M4A1_MODEL)
	}
	return PLUGIN_HANDLED
}

public CurrentWeapon(id)
{
	if ((get_user_weapon(id) == CSW_M4A1) && g_bHasFrostM4A1[id] == true)
	{
		CheckModel(id)
	}
	else
	{
		ClearSyncHud(id, g_iHudSync)
	}
	return PLUGIN_HANDLED
}

// Frost Effect Sound
public FrostEffectSound(iOrigin[3])
{
	new Entity = create_entity("info_target")

	new Float:flOrigin[3]
	IVecFVec(iOrigin, flOrigin)
	entity_set_origin(Entity, flOrigin)
	emit_sound(Entity, CHAN_WEAPON, "warcraft3/impalehit.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
}

// Frost Effect Ring
FrostEffectRing(const Float:originF3[3])
{
	// Largest ring
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, originF3, 0)
	write_byte(TE_BEAMCYLINDER) // TE id
	engfunc(EngFunc_WriteCoord, originF3[0]) // x
	engfunc(EngFunc_WriteCoord, originF3[1]) // y
	engfunc(EngFunc_WriteCoord, originF3[2]) // z
	engfunc(EngFunc_WriteCoord, originF3[0]) // x axis
	engfunc(EngFunc_WriteCoord, originF3[1]) // y axis
	engfunc(EngFunc_WriteCoord, originF3[2]+100.0) // z axis
	write_short(g_iM4A1FrostSpr) // sprite
	write_byte(0) // startframe
	write_byte(1) // framerate
	write_byte(3) // life
	write_byte(60) // width
	write_byte(0) // noise
	write_byte(41) // red
	write_byte(138) // green
	write_byte(255) // blue
	write_byte(200) // brightness
	write_byte(0) // speed
	message_end()
}

stock ham_strip_weapon(id,weapon[])
{
    if(!equal(weapon,"weapon_",7)) return 0

    new wId = get_weaponid(weapon)
    if(!wId) return 0

    new wEnt
    while((wEnt = engfunc(EngFunc_FindEntityByString,wEnt,"classname",weapon)) && pev(wEnt,pev_owner) != id) {}
    if(!wEnt) return 0

    if(get_user_weapon(id) == wId) ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt)

    if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) return 0
    ExecuteHamB(Ham_Item_Kill,wEnt)

    set_pev(id,pev_weapons,pev(id,pev_weapons) & ~(1<<wId))

    return 1
}

public Ham_TraceAttack_Player(iVictim, iAttacker, Float:fDamage, Float:fDeriction[3], iTraceHandle, iBitDamage)
{
	if(!is_user_alive(iAttacker))
	return

	if(get_user_weapon(iAttacker) != CSW_M4A1) return
	free_tr2(iTraceHandle)
	if(!g_bHasFrostM4A1[iAttacker]) return
	static Float:end[3]
	get_tr2(iTraceHandle, TR_vecEndPos, end)

	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_BEAMENTPOINT)
	write_short(iAttacker | 0x1000)
	engfunc(EngFunc_WriteCoord, end[0])
	engfunc(EngFunc_WriteCoord, end[1])
	engfunc(EngFunc_WriteCoord, end[2])
	write_short(m_spritetexture)
	write_byte(1) // framerate
	write_byte(5) // framerate
	write_byte(1) // life
	write_byte(20)  // width
	write_byte(0)// noise
	write_byte(0)// r, g, b
	write_byte(100)// r, g, b
	write_byte(255)// r, g, b
	write_byte(220)	// brightness
	write_byte(150)	// speed
	message_end()
}

public fw_SetModel(entity, model[])
{
	
	if(!is_valid_ent(entity)) 
		return FMRES_IGNORED

	if(!equali(model, W_OLD_M4A1_MODEL)) 
		return FMRES_IGNORED

	new className[33]
	entity_get_string(entity, EV_SZ_classname, className, 32)

	static iOwner, iStoredM4A1ID

	// Frost M4A1 Owner
	iOwner = entity_get_edict(entity, EV_ENT_owner)

	// Get drop weapon index (Frost M4A1) to use in fw_FrostM4A1AddToPlayer forward
	iStoredM4A1ID = find_ent_by_owner(-1, "weapon_m4a1", entity)

	// If Player Has Frost M4A1 and It's weapon_m4a1
	if(g_bHasFrostM4A1[iOwner] && is_valid_ent(iStoredM4A1ID))
	{
		// Setting weapon options
		entity_set_int(iStoredM4A1ID, EV_INT_impulse, 1997)

		// Rest Var
		g_bHasFrostM4A1[iOwner] = false
		
		// Set weaponbox new model
		entity_set_model(entity, W_M4A1_MODEL)
		return FMRES_SUPERCEDE
	}
	return FMRES_IGNORED
}

public fw_FrostM4A1AddToPlayer(FrostM4A1, id)
{
	// Make sure that this is M4A1
	if(is_valid_ent(FrostM4A1) && is_user_connected(id) && entity_get_int(FrostM4A1, EV_INT_impulse) == 1997)
	{
		// Update Var
		g_bHasFrostM4A1[id] = true

		// Reset weapon options
		entity_set_int(FrostM4A1, EV_INT_impulse, 0)
		return HAM_HANDLED
	}
	return HAM_IGNORED
}

stock drop_weapons(id, dropwhat)
{
	static weapons[32], num, i, weaponid
	num = 0
	get_user_weapons(id, weapons, num)

	for (i = 0; i < num; i++)
	{
		weaponid = weapons[i]

		if (dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM))
		{
			static wname[32]
			get_weaponname(weaponid, wname, sizeof wname - 1)
			engclient_cmd(id, "drop", wname)
		}
	}
}

Last Edit: Jan 17, 2022 17:11:21 GMT by ShaunCraft15

Counter-Strike Plugins New Member :) Posts: 7	New Frost m4a1 - Mar 29, 2022 10:39:10 GMT Quote Select Post Deselect Post Link to Post Member Give Gift Back to Top Post by Counter-Strike Plugins on Mar 29, 2022 10:39:10 GMT Version zombie plague special ?
	cs16plugin.blogspot.com

New Frost m4a1 -

Post by Deleted on Jan 16, 2022 19:54:18 GMT

Post by ShaunCraft15 on Jan 17, 2022 17:06:11 GMT

Post by Counter-Strike Plugins on Mar 29, 2022 10:39:10 GMT