[REQ] Nemesis radar

so youre saying that you already done that or i have to do it myself?

im not sure how to do that zmd94

so this gives nemesis automatically radar when player is nemesis right?

Zmd there was an error while compiling i tested for you because i was intersted in so here is the fixed code:
I just corrected some expressions of "(" "{" and errors assumed to 0.

Here it is and its working fine: +karmaD for the effort:D



#include <amxmodx>
#include <hamsandwich>
#include <zombieplague>

#define PLUGIN "Zombie Plague extra item - Radar (zombie)"
#define VERSION "1.3"
#define AUTHOR "Sonic Son'edit, HoRRoR"

new g_msgHostageAdd, g_msgHostageDel, g_maxplayers, g_itemid_radar;

new player_has_radar[33];
new zp_radar_beep;
new zp_radar_show_dead;

new cvar_zp_radar_beep;
new cvar_zp_radar_show_dead;

new const sound_radar_beep[] = "player/heartbeat1.wav"


public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR)

register_event("HLTV", "event_round_start", "a")

RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")

g_msgHostageAdd = get_user_msgid("HostagePos")
g_msgHostageDel = get_user_msgid("HostageK")

cvar_zp_radar_beep = register_cvar("zp_zombie_radar_beep", "1")
cvar_zp_radar_show_dead = register_cvar("zp_zombie_radar_show_dead", "0")

g_maxplayers = get_maxplayers()

g_itemid_radar = zp_register_extra_item("Dinner Scanner", 5, ZP_TEAM_ZOMBIE)

for (new i = 1; i<=g_maxplayers;i++) player_has_radar[i] = false;

set_task (2.0,"radar_scan",_,_,_,"b");
}

public plugin_precache()
{
precache_sound(sound_radar_beep)
}

public plugin_cfg()
{
new cfgdir[32]
get_localinfo("amxx_configsdir",cfgdir,sizeof cfgdir)
server_cmd("exec %s/zp_radar_zombie.cfg", cfgdir)
}

public event_round_start()
{
if (get_pcvar_num(cvar_zp_radar_beep) == 1)
zp_radar_beep=true;
else
zp_radar_beep=false;

if (get_pcvar_num(cvar_zp_radar_show_dead) == 1)
zp_radar_show_dead=true;
else
zp_radar_show_dead=false;
}

public zp_round_started(gamemode, id)
{
if(gamemode == MODE_NEMESIS)
{
new iPlayers[32], iPlayerCount, i, player
get_players(iPlayers, iPlayerCount, "a")
for(i = 0; i < iPlayerCount; i++)
{
player = iPlayers[i]
if(zp_get_user_nemesis(player)
)

player_has_radar[player] = true
}
}
}

public zp_extra_item_selected(player, itemid)
{
if (itemid == g_itemid_radar) player_has_radar[player] = true;
}

public radar_scan()
{
new humans_count = 0;
new humans_list[32];
new HumansCoords[3];
new id, i;

for (new id=1; id<=g_maxplayers; id++)
{
if (zp_radar_show_dead)
{
if (!(zp_get_user_zombie(id) || zp_get_user_nemesis(id)))
{
humans_count++;
humans_list[humans_count]=id;
}
}
else
{
if ((!(zp_get_user_zombie(id) || zp_get_user_nemesis(id)))&&(is_user_alive(id)))
{
humans_count++;
humans_list[humans_count]=id;
}
}
}

for (id=1; id<=g_maxplayers; id++)
{
if ((!is_user_alive(id))||(!player_has_radar[id])) continue;

for (i=1;i<=humans_count;i++)
{
get_user_origin(humans_list[i], HumansCoords)

message_begin(MSG_ONE_UNRELIABLE, g_msgHostageAdd, {0,0,0}, id)
write_byte(id)
write_byte(i)
write_coord(HumansCoords[0])
write_coord(HumansCoords[1])
write_coord(HumansCoords[2])
message_end()

message_begin(MSG_ONE_UNRELIABLE, g_msgHostageDel, {0,0,0}, id)
write_byte(i)
message_end()
}
if (zp_radar_beep) emit_sound(id, CHAN_ITEM, sound_radar_beep, 1.0, ATTN_NORM, 0, PITCH_NORM);
}
}

public zp_user_infected_post(id, infector)
{
player_has_radar[id] = false;
}

public fw_PlayerKilled(victim, attacker, shouldgib)
{
player_has_radar[victim] = false;
}

public zp_round_ended(winteam)
{
for (new id=1; id<=g_maxplayers; id++)
player_has_radar[id] = false;
}

Nice, Pervade.

By the way, I have optimized the code. Just use below:

#include <amxmodx>
#include <zombieplague>

#define TASK_HUD 1994

new const g_RadarSound[] = "player/heartbeat1.wav"

new bool:g_bPlayerHasRadar[33]
new g_iRadarBeep, g_iRadarShowDead
new g_msgHostageAdd, g_msgHostageDel, g_iMaxPlayers
new g_iRadarScan

public plugin_init()
{
register_plugin("Zombie Radar", "1.0", "zmd94")

g_iRadarShowDead = register_cvar("zr_show_dead", "1")
g_iRadarBeep = register_cvar("zr_beep_sound", "1")

g_msgHostageAdd = get_user_msgid("HostagePos")
g_msgHostageDel = get_user_msgid("HostageK")
g_iMaxPlayers = get_maxplayers()
}

public plugin_precache()
{
g_iRadarScan = zp_register_extra_item("Human Locator", 5, ZP_TEAM_ZOMBIE)
precache_sound(g_RadarSound)
}

public zp_round_started(gamemode, id)
{
set_task(1.0, "RadarScan", TASK_HUD, _, _, "b")
}

public zp_round_ended(winteam)
{
remove_task(TASK_HUD)
}

public zp_extra_item_selected(id, itemid)
{
if (itemid == g_iRadarScan)
{
g_bPlayerHasRadar[id] = true
}
}

public zp_user_infected_post(id, infector)
{
g_bPlayerHasRadar[id] = false

if(zp_is_nemesis_round() && zp_get_user_nemesis(id))
{
g_bPlayerHasRadar[id] = true
}
}

public zp_user_humanized_post(id)
{
g_bPlayerHasRadar[id] = false
}

public RadarScan()
{
new HumanCount = 0
new HumanList[32], HumansCoords[3]
new RadarShowDead = get_pcvar_num(g_iRadarShowDead)

for (new id = 1; id <= g_iMaxPlayers; id++)
{
if(RadarShowDead)
{
if (!zp_get_user_zombie(id) && !zp_get_user_nemesis(id))
{
HumanCount++
HumanList[HumanCount] = id
}
}
else
{
if (is_user_alive(id) && !zp_get_user_zombie(id) && !zp_get_user_nemesis(id))
{
HumanCount++;
HumanList[HumanCount]=id;
}
}
}

new RadarBeep = get_pcvar_num(g_iRadarBeep)
new id, i
for (id = 1; id <= g_iMaxPlayers; id++)
{
if (!is_user_alive(id) || !g_bPlayerHasRadar[id])
continue

for(i = 1; i<= HumanCount; i++)
{
get_user_origin(HumanList[i], HumansCoords)

message_begin(MSG_ONE_UNRELIABLE, g_msgHostageAdd, {0,0,0}, id)
write_byte(id)
write_byte(i)
write_coord(HumansCoords[0])
write_coord(HumansCoords[1])
write_coord(HumansCoords[2])
message_end()

message_begin(MSG_ONE_UNRELIABLE, g_msgHostageDel, {0,0,0}, id)
write_byte(i)
message_end()
}

if(RadarBeep)
{
emit_sound(id, CHAN_ITEM, g_RadarSound, 1.0, ATTN_NORM, 0, PITCH_NORM)
}
}
}

Welcome.