[req] Chat Translation plugin

eimad
New Member

Posts: 7

[req] Chat Translation plugin Feb 1, 2015 20:41:10 GMT

Quote

Post by eimad on Feb 1, 2015 20:41:10 GMT

Hello

i want to requist plugin for translat players chat
like this but i want show translate only for admin with imm access
forums.alliedmods.net/showthread.php?t=91671

so when player use other language then the english
plugin auto translate it to english and show translated text to imm admin access only
and if you can add translat for imm admin with language option and show his translated chat to all players
is this possible if yes what is the price ?

sorry for bad english thanks...

Last Edit: Feb 1, 2015 21:04:28 GMT by eimad

zmd94
Zp Staff

Posts: 8,249

[req] Chat Translation plugin Feb 2, 2015 9:33:10 GMT

Quote

Post by zmd94 on Feb 2, 2015 9:33:10 GMT

First of all, welcome to this forum.

By the way, just try below:

/*	=============================================
*	- NAME:
*	  + Chat Translation
*
*	- DESCRIPTION:
*	  + 
*	  + This plugin will take other players chat and translate it according-
*	  + to the language the player has set in their amx_langmenu.
*	  + 
*	  + -Example-
*	  + There are 12 players speaking English (and have English set in amx_langmenu).
*	  + There are 5 players speaking German (and have German set in amx_langmenu).
*	  + There are 2 players speaking Spanish (and have Spanish set in amx_langmenu).
*	  + The players in English will now see the German's/Spanish's chat in English.
*	  + The players in German will now see the English's/Spanish's chat in German.
*	  + The players in Spanish will now see the English's/German's chat in Spanish.
*	  + 
*	  + -How it works-
*	  + Before sending the chat message to each player it will first-
*	  + send it to Google's Translation page (http://translate.google.com/translate_t).
*	  + It will now retrieve the translated text and send it on to the selected player.
*	  + If the sending and receiveing player are using the same language it won't use the translator.
*	  + 
*	  + -Limitations-
*	  + Only the languages supported in amx_langmenu are supported in this plugin.
*	  + 2 languages in amx_langmenu are also not available on Google (Macedonian and l33t).
*	  + Google Translations are not perfect. There will be errors sometimes of course.
*	  + The HL1 engine cannot display some translated characters (that char will be left out of word).
*	  + Serbian doesn't work very well so it's not included.
*	  + 
*
* 	
*	-------------
*	Server cvars:
*	-------------
*	- sv_langdomain ".com"
*	 + Sets the domain in which to use on Google for the translation.
*	 + You will want to set this to the domain closest to your server (make sure it exists first!).
*	 + Example: United States will use .com (Default), United Kingdom will use .co.uk
* 
*	- sv_langmod "mod"
*	 + Here you must set the mod name abbreviation you are using (Default: cs).
*	 + Names to choose from: CS, TFC.
* 
*	- sv_translatefile "URL"
*	 + This cvar allows you to enter the URL to the ChatTranslation.php file.
*	 + The closer the URL is to your game server the better.
*	 + If you set this cvar it will use the ChatTranslation.php file before/after translating.
*	 + The ChatTranslation.php file is good to use so it can fix non-english characters.
*	 + You can host the ChatTranslation.php yourself, it's contained in the zip file.
*	
* 	
*	----------
*	Changelog:
*	----------
*	Version 1.0 ( 05-03-2009 )
*	-- Initial release.
* 
*	Version 1.1 ( 05-03-2009 )
*	-- Added support for Team Fortress Classic.
*	-- Added the sv_langmod cvar for mod support.
* 
*	Version 1.2 ( 05-06-2009 )
*	-- Fixed quotes cutting off the sentence.
*	-- The amx_langmenu will pop-up if client doesn't have a language set.
* 
*	Version 1.3 ( 05-08-2009 )
*	-- Fixed some text display when a client doesn't select a language.
*	-- Fixed names displaying incorrectly in TFC if name used certain chars.
* 
*	Version 2.0 ( 05-09-2009 )
*	-- Fixed the menu from displaying before player fully spawned.
*	-- Removed Serbian from the translations as it doesn't work well.
*	-- Added the sv_translatefile cvar, see the cvar section to see how it works.
* 
*/

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <sockets>
#include <regex>

#define PLUGIN	"Chat Translation"
#define VERSION	"2.0"
#define AUTHOR	"hlstriker"

// Configure access flag to open war menu and start vote command. ;)
#define ADMIN_FLAG ADMIN_IMMUNITY

enum
{
	GAME_CS = 1,
	GAME_TFC
}

new g_hSocketPool[64];
new g_msgSayText;
new g_szGoogleServer[48];
new g_iModNum;
new bool:g_bHasSpawned[33];

/* For the PHP script */
new bool:g_bHasTransFile;
new g_szDNS[64];
new g_szDomain[8];
new g_szPathToTransFile[192];

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_cvar("chattrans_version", VERSION, FCVAR_SERVER|FCVAR_SPONLY);
	g_msgSayText = get_user_msgid("SayText");
	register_message(g_msgSayText, "msg_SayText");
	
	register_event("ResetHUD", "hook_ResetHUD", "be");
	
	register_cvar("sv_langdomain", ".com", FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_UNLOGGED|FCVAR_SPONLY);
	get_cvar_string("sv_langdomain", g_szGoogleServer, sizeof(g_szGoogleServer)-1);
	copy(g_szDomain, sizeof(g_szDomain), g_szGoogleServer);
	format(g_szGoogleServer, sizeof(g_szGoogleServer)-1, "translate.google%s", g_szGoogleServer);
	
	new szMod[6];
	register_cvar("sv_langmod", "cs", FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_UNLOGGED|FCVAR_SPONLY);
	get_cvar_string("sv_langmod", szMod, sizeof(szMod)-1);
	if(equali(szMod, "cs"))
		g_iModNum = GAME_CS;
	else if(equali(szMod, "tfc"))
		g_iModNum = GAME_TFC;
	else g_iModNum = 0;
	
	/* URL to the php script */
	new szTranslateFile[256];
	register_cvar("sv_translatefile", "http://hldevs.com/ChatTranslation/ChatTranslation.php", FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_UNLOGGED|FCVAR_SPONLY);
	get_cvar_string("sv_translatefile", szTranslateFile, sizeof(szTranslateFile)-1);
	
	new Regex:hRegex, iRet, szError[32];
	hRegex = regex_match(szTranslateFile, "(http://)?(www.)?(.+?)(/.+?\.php)", iRet, szError, sizeof(szError));
	if(hRegex >= REGEX_OK)
	{
		regex_substr(hRegex, 3, g_szDNS, sizeof(g_szDNS)-1);
		regex_substr(hRegex, 4, g_szPathToTransFile, sizeof(g_szPathToTransFile)-1);
		regex_free(hRegex);
		g_bHasTransFile = true;
	}
	else g_bHasTransFile = false;
}

public client_connect(iClient)
	g_bHasSpawned[iClient] = false;

public hook_ResetHUD(iClient)
{
	if(!g_bHasSpawned[iClient])
	{
		g_bHasSpawned[iClient] = true;
		
		new szLanguage[4];
		engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, iClient), "lang", szLanguage, sizeof(szLanguage)-1);
		if(equal(szLanguage, "") || strlen(szLanguage) > 2)
			set_task(1.2, "task_LangMenu", iClient+48281, _, _, "b");
	}
}

public task_LangMenu(iClient)
{
	if(!is_user_connected(iClient-48281))
	{
		if(task_exists(iClient))
			remove_task(iClient);
		return PLUGIN_CONTINUE;
	}
	
	if(is_user_alive(iClient))
	{
		if(task_exists(iClient))
			remove_task(iClient);
		client_cmd(iClient-48281, "amx_langmenu");
	}
	
	return PLUGIN_CONTINUE;
}

public msg_SayText(iMsgID, iDest, iReceiver)
{
	if(!g_iModNum || !is_user_connected(iReceiver) || !get_user_flags(iReceiver) & ADMIN_FLAG)
		return PLUGIN_CONTINUE;
	
	static iSender;
	iSender = get_msg_arg_int(1);
	if(!get_user_flags(iSender) & ADMIN_FLAG || iSender == iReceiver)
		return PLUGIN_CONTINUE;
	
	new szLangFrom[3], szLangTo[3];
	engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, iSender), "lang", szLangFrom, sizeof(szLangFrom)-1);
	engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, iReceiver), "lang", szLangTo, sizeof(szLangTo)-1);
	
	/* If players don't have a language set it to english */
	if(equal(szLangFrom, ""))
		copy(szLangFrom, sizeof(szLangFrom), "en");
	else if(equal(szLangTo, ""))
		copy(szLangTo, sizeof(szLangTo), "en");
	
	if(equal(szLangFrom, szLangTo))
		return PLUGIN_CONTINUE;
	
	/* macedonian and l33t can't be translated, and Serbian doesn't work well at all */
	if(equal(szLangFrom, "mk") || equal(szLangFrom, "ls") || equal(szLangFrom, "sr"))
		return PLUGIN_CONTINUE;
	
	/* Change Brazil Portuguese to just Portuguese */
	if(equal(szLangFrom, "bp"))
		copy(szLangFrom, sizeof(szLangFrom), "pt");
	else if(equal(szLangTo, "bp"))
		copy(szLangTo, sizeof(szLangTo), "pt");
	
	/* Change Czech's abbreviation to be correct with googles */
	if(equal(szLangFrom, "cz"))
		copy(szLangFrom, sizeof(szLangFrom), "cs");
	else if(equal(szLangTo, "cz"))
		copy(szLangTo, sizeof(szLangTo), "cs");
	
	static szMsgType[64], szText[193];
	
	if(g_iModNum == GAME_CS)
	{
		get_msg_arg_string(2, szMsgType, sizeof(szMsgType));
		get_msg_arg_string(4, szText, sizeof(szText));
	}
	else if(g_iModNum == GAME_TFC)
	{
		/* In TFC there is no msg type, but the players name is part of the msg */
		static szRegex[256];
		get_msg_arg_string(2, szText, sizeof(szText));
		get_user_name(iSender, szMsgType, sizeof(szMsgType));
		format(szRegex, sizeof(szRegex), "(.+?%s): (.+?)^n", szMsgType);
		
		static Regex:hRegex, iRet, szError[32];
		hRegex = regex_match(szText, szRegex, iRet, szError, sizeof(szError));
		if(hRegex >= REGEX_OK)
		{
			regex_substr(hRegex, 2, szText, sizeof(szText));
			regex_free(hRegex);
		}
		else return PLUGIN_CONTINUE;
	}
	
	TranslateText(szText, szMsgType, szLangFrom, szLangTo, iSender, iReceiver)
	
	return PLUGIN_HANDLED;
}

TranslateText(szText[193], const szMsgType[64], const szLangFrom[3], const szLangTo[3], iSender, iReceiver)
{
	trim(szText);
	replace_all(szText, sizeof(szText), " ", "%20");
	replace_all(szText, sizeof(szText), "^"", "");
	replace_all(szText, sizeof(szText), "'", "");
	
	static szBuffer[512], iLen; iLen = 0;
	if(g_bHasTransFile)
	{
		iLen = format(szBuffer[iLen], sizeof(szBuffer)-iLen, "GET %s?domain=%s&text=%s&sl=%s&tl=%s HTTP/1.1^r^n", g_szPathToTransFile, g_szDomain, szText, szLangFrom, szLangTo);
		iLen += format(szBuffer[iLen], sizeof(szBuffer)-iLen, "Host: %s^r^n", g_szDNS);
		iLen += format(szBuffer[iLen], sizeof(szBuffer)-iLen, "Connection: Close^r^n^r^n");
	}
	else
	{
		iLen = format(szBuffer[iLen], sizeof(szBuffer)-iLen, "GET /translate_a/t?client=t&text=%s&sl=%s&tl=%s HTTP/1.1^r^n", szText, szLangFrom, szLangTo);
		iLen += format(szBuffer[iLen], sizeof(szBuffer)-iLen, "Host: %s^r^n", g_szGoogleServer);
		iLen += format(szBuffer[iLen], sizeof(szBuffer)-iLen, "Connection: Close^r^n^r^n");
	}
	
	static i, iErr;
	for(i=0; i<sizeof(g_hSocketPool); i++)
	{
		if(!g_hSocketPool[i])
		{
			if(g_bHasTransFile)
				g_hSocketPool[i] = socket_open(g_szDNS, 80, SOCKET_TCP, iErr);
			else
				g_hSocketPool[i] = socket_open(g_szGoogleServer, 80, SOCKET_TCP, iErr);
			break;
		}
	}
	
	if(!iErr)
	{
		static iPack[64]; iPack[0] = i; iPack[1] = iSender; iPack[2] = iReceiver;
		format(iPack[3], sizeof(iPack), "%s", szMsgType);
		socket_send(g_hSocketPool[i], szBuffer, strlen(szBuffer));
		CheckSocket(iPack);
	}
}

public CheckSocket(iPack[64])
{
	static i, iSender, iReceiver;
	i = iPack[0]; iSender = iPack[1]; iReceiver = iPack[2];
	
	if(socket_change(g_hSocketPool[i], 100))
	{
		static szBuffer[3072];
		socket_recv(g_hSocketPool[i], szBuffer, sizeof(szBuffer));
		socket_close(g_hSocketPool[i]);
		
		static Regex:hRegex, iRet, szError[32];
		hRegex = regex_match(szBuffer, "^"(.+?)^"", iRet, szError, sizeof(szError));
		if(hRegex >= REGEX_OK)
		{
			regex_substr(hRegex, 1, szBuffer, sizeof(szBuffer));
			regex_free(hRegex);
			
			static szMsgType[64];
			format(szMsgType, sizeof(szMsgType), "%s", iPack[3]);
			
			static szLangFrom[3], szLangTo[3];
			engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, iSender), "lang", szLangFrom, sizeof(szLangFrom)-1);
			engfunc(EngFunc_InfoKeyValue, engfunc(EngFunc_GetInfoKeyBuffer, iReceiver), "lang", szLangTo, sizeof(szLangTo)-1);
			strtoupper(szLangFrom);
			strtoupper(szLangTo);
			
			/* If players don't have a language set it to english */
			if(equal(szLangFrom, ""))
				copy(szLangFrom, sizeof(szLangFrom), "EN");
			else if(equal(szLangTo, ""))
				copy(szLangTo, sizeof(szLangTo), "EN");
			
			format(szBuffer, sizeof(szBuffer), "[%s->%s] %s^r^n", szLangFrom, szLangTo, szBuffer);
			szBuffer[192] = '^0';
			
			if(g_iModNum == GAME_CS)
			{
				message_begin(MSG_ONE, g_msgSayText, _, iReceiver);
				write_byte(iSender);
				write_string(szMsgType);
				write_string("");
				write_string(szBuffer);
				message_end();
			}
			else if(g_iModNum == GAME_TFC)
			{
				format(szBuffer, sizeof(szBuffer), "^x02%s: %s", szMsgType, szBuffer);
				message_begin(MSG_ONE, g_msgSayText, _, iReceiver);
				write_byte(iSender);
				write_string(szBuffer);
				message_end();
			}
		}
		
		g_hSocketPool[i] = 0;
	}
	
	if(g_hSocketPool[i])
		set_task(0.1, "CheckSocket", _, iPack, sizeof(iPack));
}

Personal message only for paid request. If you love this forum, kindly to donate by clicking the donate button at the footer of this forum.

eimad New Member Posts: 7	[req] Chat Translation plugin Feb 2, 2015 15:30:17 GMT Quote Select Post Deselect Post Link to Post Member Give Gift Back to Top Post by eimad on Feb 2, 2015 15:30:17 GMT thank you very much i will try this

zmd94 Zp Staff Posts: 8,249	[req] Chat Translation plugin Feb 2, 2015 15:33:56 GMT Quote Select Post Deselect Post Link to Post Member Give Gift Back to Top Post by zmd94 on Feb 2, 2015 15:33:56 GMT Alright, just let me know if there are any problems.
	Personal message only for paid request. If you love this forum, kindly to donate by clicking the donate button at the footer of this forum.

[req] Chat Translation plugin

Post by eimad on Feb 1, 2015 20:41:10 GMT

Post by zmd94 on Feb 2, 2015 9:33:10 GMT

Post by eimad on Feb 2, 2015 15:30:17 GMT

Post by zmd94 on Feb 2, 2015 15:33:56 GMT