Block Extra Menu In Gamemodes

for humans?

Make sure allow this includes to work correctly

#include <zp50_items>
#include <zp50_gamemodes>

Add this variables:

new g_GameModeInfectionID, g_GameModeMultiID

add this
public plugin_cfg()
{
g_GameModeInfectionID = zp_gamemodes_get_id("Infection Mode")
g_GameModeMultiID = zp_gamemodes_get_id("Multiple Infection Mode")

}

Add this to ur item:

public zp_fw_items_select_pre(id, itemid, ignorecost)
{
        // This is not our item
if (itemid != g_itemid)
return ZP_ITEM_AVAILABLE;

if (zp_core_is_zombie(id))
        return ZP_ITEM_DONT_SHOW;

     
new current_mode = zp_gamemodes_get_current()

if (current_mode != g_GameModeInfectionID && current_mode != g_GameModeMultiID)

return ZP_ITEM_DONT_SHOW;



return ZP_ITEM_AVAILABLE;

}

And Test it and tell me if this not work or work

Compiled + work but if the round is normal infection or any other gamemode it show "you can't open extra item menu in assassin round", i only want to block assassin and nemesis round.

/*================================================================================

----------------------
-*- [ZP] Main Menu -*-
----------------------

This plugin is part of Zombie Plague Mod and is distributed under the
terms of the GNU General Public License. Check ZP_ReadMe.txt for details.

================================================================================*/

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#define LIBRARY_BUYMENUS "zp50_buy_menus"
#include <zp50_buy_menus>
#define LIBRARY_ZOMBIECLASSES "zp50_class_zombie"
#include <zp50_class_zombie>
#define LIBRARY_HUMANCLASSES "zp50_class_human"
#include <zp50_class_human>
#define LIBRARY_ITEMS "zp50_items"
#include <zp50_items>
#define LIBRARY_ADMIN_MENU "zp50_admin_menu"
#include <zp50_admin_menu>
#define LIBRARY_RANDOMSPAWN "zp50_random_spawn"
#include <zp50_random_spawn>
#include <zp50_colorchat>
#include <zp50_colorchat_const>
#include <zp50_gamemodes>
#include <zombieplague>

#define ZP_PREFIX "[ZoD*|] "

#define TASK_WELCOMEMSG 100
// CS Player PData Offsets (win32)
const OFFSET_CSMENUCODE = 205

// Menu keys
const KEYSMENU = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3|MENU_KEY_4|MENU_KEY_5|MENU_KEY_6|MENU_KEY_7|MENU_KEY_8|MENU_KEY_9|MENU_KEY_0

#define flag_get(%1,%2) (%1 & (1 << (%2 & 31)))
#define flag_get_boolean(%1,%2) (flag_get(%1,%2) ? true : false)
#define flag_set(%1,%2) %1 |= (1 << (%2 & 31))
#define flag_unset(%1,%2) %1 &= ~(1 << (%2 & 31))

new g_ChooseTeamOverrideActive

new cvar_buy_custom_primary, cvar_buy_custom_secondary, cvar_buy_custom_grenades
new cvar_random_spawning

public plugin_init()
{
register_plugin("[ZP] Main Menu", ZP_VERSION_STRING, "ZP Dev Team")

register_event("HLTV", "event_round_start", "a", "1=0", "2=0")

register_clcmd("chooseteam", "clcmd_chooseteam")

register_clcmd("say /zpmenu", "clcmd_zpmenu")
register_clcmd("say zpmenu", "clcmd_zpmenu")

// Menus
register_menu("Main Menu", KEYSMENU, "menu_main")
}

public plugin_natives()
{
set_module_filter("module_filter")
set_native_filter("native_filter")
}
public module_filter(const module[])
{
if (equal(module, LIBRARY_BUYMENUS) || equal(module, LIBRARY_ZOMBIECLASSES) || equal(module, LIBRARY_HUMANCLASSES) || equal(module, LIBRARY_ITEMS) || equal(module, LIBRARY_ADMIN_MENU) || equal(module, LIBRARY_RANDOMSPAWN))
return PLUGIN_HANDLED;

return PLUGIN_CONTINUE;
}
public native_filter(const name[], index, trap)
{
if (!trap)
return PLUGIN_HANDLED;

return PLUGIN_CONTINUE;
}

public plugin_cfg()
{
cvar_buy_custom_primary = get_cvar_pointer("zp_buy_custom_primary")
cvar_buy_custom_secondary = get_cvar_pointer("zp_buy_custom_secondary")
cvar_buy_custom_grenades = get_cvar_pointer("zp_buy_custom_grenades")
cvar_random_spawning = get_cvar_pointer("zp_random_spawning_csdm")
}

// Event Round Start
public event_round_start()
{
// Show main menu message
remove_task(TASK_WELCOMEMSG)
set_task(2.0, "task_welcome_msg", TASK_WELCOMEMSG)
}

// Welcome Message Task
public task_welcome_msg()
{
client_print(0, print_chat, "[ZoD*|] Welcome To ZoD*| Zombie Plague", ZP_VERSION_STR_LONG)
}

public clcmd_chooseteam(id)
{
if (flag_get(g_ChooseTeamOverrideActive, id))
{
show_menu_main(id)
return PLUGIN_HANDLED;
}

flag_set(g_ChooseTeamOverrideActive, id)
return PLUGIN_CONTINUE;
}

public clcmd_zpmenu(id)
{
show_menu_main(id)
}

public client_putinserver(id)
{
flag_set(g_ChooseTeamOverrideActive, id)
}

// Main Menu
show_menu_main(id)
{
static menu[250]
new len

// Title
len += formatex(menu[len], charsmax(menu) - len, "\yZombie Plague^n^n")

// 1. Buy menu
if (LibraryExists(LIBRARY_BUYMENUS, LibType_Library) && (get_pcvar_num(cvar_buy_custom_primary)
|| get_pcvar_num(cvar_buy_custom_secondary) || get_pcvar_num(cvar_buy_custom_grenades)) && is_user_alive(id))
len += formatex(menu[len], charsmax(menu) - len, "1.\w %L^n", id, "MENU_BUY")
else
len += formatex(menu[len], charsmax(menu) - len, "1. %L^n", id, "MENU_BUY")

// 2. Extra Items
if (LibraryExists(LIBRARY_ITEMS, LibType_Library) && is_user_alive(id) && zp_has_round_started() && zp_is_assassin_round() && zp_is_nemesis_round())
len += formatex(menu[len], charsmax(menu) - len, "2.\w %L^n", id, "MENU_EXTRABUY")
else
len += formatex(menu[len], charsmax(menu) - len, "2. %L^n", id, "MENU_EXTRABUY")

// 3. Zombie class
if (LibraryExists(LIBRARY_ZOMBIECLASSES, LibType_Library) && zp_class_zombie_get_count() > 1)
len += formatex(menu[len], charsmax(menu) - len, "3.\w %L^n", id, "MENU_ZCLASS")
else
len += formatex(menu[len], charsmax(menu) - len, "3. %L^n", id, "MENU_ZCLASS")

// 4. Unstuck
if (LibraryExists(LIBRARY_RANDOMSPAWN, LibType_Library) && is_user_alive(id))
len += formatex(menu[len], charsmax(menu) - len, "4.\w %L^n", id, "MENU_UNSTUCK")
else
len += formatex(menu[len], charsmax(menu) - len, "4. %L^n", id, "MENU_UNSTUCK")

// 5. Help
len += formatex(menu[len], charsmax(menu) - len, "5.\w %L^n^n", id, "MENU_HELP")

// 6. FPS
len += formatex(menu[len], charsmax(menu) - len, "6.\w %L^n^n", id, "MENU_FPS")

// 7: Choose Team
len += formatex(menu[len], charsmax(menu) - len, "7.\w %L^n^n", id, "MENU_CHOOSE_TEAM")

// 8. VIP Menu
len += formatex(menu[len], charsmax(menu) - len, "8.\w %L^n", id, "MENU_VIP")

// 9. Admin menu
if (LibraryExists(LIBRARY_ADMIN_MENU, LibType_Library) && is_user_admin(id))
len += formatex(menu[len], charsmax(menu) - len, "9.\w %L", id, "MENU_ADMIN")
else
len += formatex(menu[len], charsmax(menu) - len, "9. %L", id, "MENU_ADMIN")

// 0. Exit
len += formatex(menu[len], charsmax(menu) - len, "^n^n0.\w %L", id, "MENU_EXIT")

// Fix for AMXX custom menus
set_pdata_int(id, OFFSET_CSMENUCODE, 0)
show_menu(id, KEYSMENU, menu, -1, "Main Menu")
}

// Main Menu
public menu_main(id, key)
{
// Player disconnected?
if (!is_user_connected(id))
return PLUGIN_HANDLED;

switch (key)
{
case 0: // Buy Menu
{
// Custom buy menus enabled?
if (LibraryExists(LIBRARY_BUYMENUS, LibType_Library) && (get_pcvar_num(cvar_buy_custom_primary)
|| get_pcvar_num(cvar_buy_custom_secondary) || get_pcvar_num(cvar_buy_custom_grenades)))
{
// Check whether the player is able to buy anything
if (is_user_alive(id))
zp_buy_menus_show(id)
else
client_print(id, print_chat, "%L", id, "CANT_BUY_WEAPONS_DEAD")
}
else
client_print(id, print_chat, "%L", id, "CUSTOM_BUY_DISABLED")
}
case 1: // Extra Items
{
// Items enabled?
if (LibraryExists(LIBRARY_ITEMS, LibType_Library))
{
if(zp_gamemodes_get_current() == ZP_NO_GAME_MODE)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items when round not started!")
return;
}
if(zp_gamemodes_get_current() == zp_is_assassin_round)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items on assassin round!")
return;
}
if(zp_gamemodes_get_current() == zp_is_nemesis_round)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items on nemesis round!")
return;
}
if(!is_user_alive(id))
{
client_print(id, print_chat, "%L", id, "CANT_BUY_ITEMS_DEAD")
return;
}
zp_items_show_menu(id)
}
else
client_print(id, print_chat, "%L", id, "CMD_NOT_EXTRAS")
}
case 3:
{
// Check if player is stuck
if (LibraryExists(LIBRARY_RANDOMSPAWN, LibType_Library) && is_user_alive(id))
{
if (is_player_stuck(id))
{
// Move to an initial spawn
if (get_pcvar_num(cvar_random_spawning))
zp_random_spawn_do(id, true) // random spawn (including CSDM)
else
zp_random_spawn_do(id, false) // regular spawn
}
else
client_print(id, print_chat, "%L", id, "CMD_NOT_STUCK")
}
else
client_print(id, print_chat, "%L", id, "CMD_NOT")
}
case 4: // Help Menu
{
show_help(id)
}
case 5: // FPS
{
client_cmd(id, "say /fps")
}
case 6: // Choose Team
{
flag_unset(g_ChooseTeamOverrideActive, id)
client_cmd(id, "chooseteam")
}
case 7: // VIP Menu
{
client_cmd(id, "vipm")
}
case 8: // Admin Menu
{
if (LibraryExists(LIBRARY_ADMIN_MENU, LibType_Library) && is_user_admin(id))
zp_admin_menu_show(id)
else
client_print(id, print_chat, "%L", id, "NO_ADMIN_MENU")
}
}
return PLUGIN_HANDLED;

}

// Help MOTD
show_help(id)
{
static motd[1024]
new len

len += formatex(motd[len], charsmax(motd) - len, "%L", id, "MOTD_INFO11", "Zombie Plague Mod", ZP_VERSION_STR_LONG, "ZP Dev Team")
len += formatex(motd[len], charsmax(motd) - len, "%L", id, "MOTD_INFO12")

show_motd(id, motd)
}

// Check if a player is stuck (credits to VEN)
stock is_player_stuck(id)
{
static Float:originF[3]
pev(id, pev_origin, originF)

engfunc(EngFunc_TraceHull, originF, originF, 0, (pev(id, pev_flags) & FL_DUCKING) ? HULL_HEAD : HULL_HUMAN, id, 0)

if (get_tr2(0, TR_StartSolid) || get_tr2(0, TR_AllSolid) || !get_tr2(0, TR_InOpen))
return true;

return false;
}

that one will work fine but it's easy to avoid by writing /items to open the extra items, to solve it just remove those edits from the zp50_main_menu.sma go to zp50_items.sma
add the include
#include <zp50_gamemodes>

add x new variables for your modes
new Mode1, Mode2 // and so on
find public plugin_cfg(), if there is no one create it yourself and add the 2 lines, if there is one just add the 2 lines under whatever is there.

public plugin_cfg()
{
Mode1 = zp_gamemodes_get_id("Nemesis Mode")
Mode2 = zp_gamemodes_get_id("Assassin Mode")
}

look for the public clcmd_items(id), it should look like this:
public clcmd_items(id)
{
// Player dead
if (!is_user_alive(id))
return;
show_items_menu(id)
}

change it to this:
public clcmd_items(id)
{
// Player dead
if (!is_user_alive(id))
return;
if(zp_gamemodes_get_current() == ZP_NO_GAME_MODE)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items when round not started!")
return;
}
if(zp_gamemodes_get_current() == Mode1)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items on Nemesis round!")
return;
}
if(zp_gamemodes_get_current() == Mode2)
{
client_print(id, print_chat, "[ZoD*|] You can't buy extra items on Assassin round!")
return;
}
show_items_menu(id)
}

Now players can't abuse /items. you can keep the menu as it is with the edits and remove the client_print from the edits above.